How to find a folder in outlook when you accidentally moved it

I’ve accidentally moved a folder when I tried to select a different folder. I’m now not able to find back the folder anymore to move it back where it belongs. I’ve got a lot of folders so going through each and every one of them isn’t really an option.

Is there a way in Outlook to search for a folder name?

No, Outlook doesn’t have an option like that, but there are other ways to locate your folder again as well.

Which method works best for you depends a bit on how long ago you might have moved it and whether or not you can remember (part of) the folder name or what should be in that folder.

Method 1: Search nearby folders

Since you’ve moved them by dragging and dropping, the folder really can’t be that far. The furthest it can go is 1 folder below any of the folders that are visible to you now. It cannot suddenly go 3 or 4 levels deeper.

By expanding the folder via the plus characters (+) or arrows next to the folders, you should be able to reveal your moved folder.

Use the plus or arrow icons to expand the folders.

Method 2: Full Folder list

When you’ve noticed your accidental moving a little bit later, then the above method will not help you anymore. To prevent you from needing to click through every folder, you can also get a list of folders via the Folder Size option;

1. Right click on the root of your mailbox.
2. Choose Properties.
3. Click the Folder Size… button

When using Office 365 with the Single Line Ribbon interface, you can access this same dialog via;

• File-> section: Info-> button: Tools-> Mailbox Cleanup…-> View Mailbox Size…

Outlook will now list all your folders in an easy to scroll window so you can quickly review the names of the folders that you have. It will also reveal the full folder path so that you can easily browse to it once you’ve found it.

Using the Folder Size dialog to find back a folder by name.

Note 1: If you already have an idea under which folder the moved folder could be, you can also use the Folder Size button of that folder to narrow down your search.

Note 2: Unfortunately, you cannot export the folder list shown here to more easily search in it with a text editor like Notepad. To do this, you can use a vbs-script (recommended) or vba-macro from the article; Export or print folder list

Method 3: Search for an item with Instant Search

If you still know of an item that was in that folder, doing a mailbox-wide search for it will also allow you to reveal which folder the message is in.

To do this, click in the Search field above your item list or press CTRL+E and then press CTRL+ALT+A to set the search scope to “All Outlook Items”.

When you’ve found the message, open it via a double-click and then press CTRL+SHIFT+F to open the Advanced Find dialog. By default, the scope of the Advanced Find dialog is set to the folder the item resides in.

By pressing on the Browse… button in the Advanced Find dialog, you’ll see where in your mailbox that folder is located.

Via Instant Search and Advanced Find, it is possible to locate a folder.

Method 4: Search for an item with Windows Search

Yet another way to relocate your folder is to search for an item that you know was in that folder via Windows Search. The results will reveal the folder path of the item that was found.

An easy way to do this in Windows 7 (but no longer for Outlook 2013 or Windows 8 and later) is by searching for the message via the Search box in the Start Menu. When the message shows up, right click it and choose “Show Conversation”. An Explorer window will open now with the search results. When you set your view to the Details view, you’ll see the Folder column which shows the full path to the folder. The name between parenthesis is the name of the mailbox or pst-file as it appears in Outlook.

Use the Details view in Explorer to show the Folder column.

Note: To switch to the Details view in Explorer in Windows 7, you can press the “Change your view” button or press the ALT button on your keyboard to make the View menu visible and then choose Details.

Method 5: VBA macro: Find a folder by its name

If you know (part of) the name of the folder that you misplaced, then you can also use the FindFolder macro from VBOffice.

Private m_Folder As Outlook.MAPIFolder
Private m_Find As String
Private m_Wildcard As Boolean
Private Const SpeedUp As Boolean = True
Private Const StopAtFirstMatch As Boolean = True
Public Sub FindFolder()
  Dim Name$
  Dim Folders As Outlook.Folders
  Set m_Folder = Nothing
  m_Find = ""
  m_Wildcard = False
  Name = InputBox("Find name:", "Search folder")
  If Len(Trim$(Name)) = 0 Then Exit Sub
  m_Find = Name
  m_Find = LCase$(m_Find)
  m_Find = Replace(m_Find, "%", "*")
  m_Wildcard = (InStr(m_Find, "*"))
  Set Folders = Application.Session.Folders
  LoopFolders Folders
  If Not m_Folder Is Nothing Then
    If MsgBox("Activate folder: " & vbCrLf & m_Folder.FolderPath, vbQuestion Or vbYesNo) = vbYes Then
      Set Application.ActiveExplorer.CurrentFolder = m_Folder
    End If
  Else
    MsgBox "Not found", vbInformation
  End If
End Sub
Private Sub LoopFolders(Folders As Outlook.Folders)
  Dim F As Outlook.MAPIFolder
  Dim Found As Boolean
  
  If SpeedUp = False Then DoEvents
  For Each F In Folders
    If m_Wildcard Then
      Found = (LCase$(F.Name) Like m_Find)
    Else
      Found = (LCase$(F.Name) = m_Find)
    End If
    If Found Then
      If StopAtFirstMatch = False Then
        If MsgBox("Found: " & vbCrLf & F.FolderPath & vbCRLF & vbCrLf & "Continue?", vbQuestion Or vbYesNo) = vbYes Then
          Found = False
        End If
      End If
    End If
    If Found Then
      Set m_Folder = F
      Exit For
    Else
      LoopFolders F.Folders
      If Not m_Folder Is Nothing Then Exit For
    End If
  Next
End Sub

Once it has found the folder, it offers you to open it directly so you can locate it and move it back where it belongs.

Find a folder by its name via a VBA macro from VBOffice.